UPD6121G产生的遥控编码是连续的32位二进制码组，其中前16位为用户识别码，能区别不同的电器设备，防止不同机种遥控码互相干扰。该芯片的用户识别码固定为十六进制01H；后16位为8位操作码（功能码）及其反码。UPD6121G最多额128种不同组合的编码。

　　当遥控器在按键按下后，周期性地发出同一种32位二进制码，周期约为108ms。一组码本身的持续时间随它包含的二进制“0”和“1”的个数不同而不同，大约在45～63ms之间，图4为发射波形图。

　　当一个键按下超过36ms，振荡器使芯片激活，将发射一组108ms的编码脉冲,这108ms发射代码由一个起始码（9ms）,一个结果码（4.5ms）,低8位地址码（9ms~18ms）,高8位地址码（9ms~18ms）,8位数据码（9ms~18ms）和这8位数据的反码（9ms~18ms）组成。如果键按下超过108ms仍未松开，接下来发射的代码（连发代码）将仅由起始码（9ms）和结束码（2.5ms）组成。

　代码格式（以接收代码为准，接收代码与发射代码反向）
　　
　　① 位定义

　 　

　　② 单发代码格式
　
　 　
　 　 　 　
　　③ 连发代码格式

　 　

　　注：代码宽度算法：

　　16位地址码的最短宽度：1.12×16=18ms 16位地址码的最长宽度：2.24ms×16=36ms

　　已知8位数据代码及其8位反代码的宽度和不变：（1.12ms+2.24ms）×8=27ms

　　∴ 32位代码的宽度为（18ms+27ms）~(36ms+27ms)

　　1． 解码的关键是如何识别“0”和“1”，从位的定义我们可以发现“0”、“1”均以0.56ms的低电平开始，不同的是高电平的宽度不同，“0”为0.56ms,“1”为1.68ms,所以必须根据高电平的宽度区别“0”和“1”。如果从0.56ms低电平过后，开始延时，0.56ms以后，若读到的电平为低，说明该位为“0”，反之则为“1”，为了可*起见，延时必须比0.56ms长些，但又不能超过1.12ms,否则如果该位为“0”，读到的已是下一位的高电平，因此取（1.12ms+0.56ms）/2=0.84ms最为可*，一般取0.84ms左右均可。

　　2． 根据码的格式，应该等待9ms的起始码和4.5ms的结果码完成后才能读码。

　【红外遥控解码实验硬件】

　　一体化红外线接收器是一种集红外线接收和放大整形于一体，不需要任何外接元件，就能完成从红外线接收到输出与TTL电平信号兼容的所有工作，而体积又很小巧，它适合于各种红外线遥控和红外线数据传输，广泛用于电视机、卫星接收机、VCD、DVD、音响、空调等家用电器中接收红外信号，图5是一体化接收头的引脚排列图，图6是本站产品配套的采用屏蔽线焊接的一体化红外接收头，采用屏蔽线焊接，抗干扰能力强，接收更可*。没有购买实验板配套的一体化红外接收头的网友可以根据图2所示接收头引脚排列图自己焊接一个。

图5：一体化红外接收头 （引脚排列图）		图6：本站产品配套一体化红外接收头（已经用屏蔽线焊接好，抗干扰能力强，插入实验板即可使用）

　　下面就是我们将要进行红外遥控解码实验所要用到的硬件设备：S51增强型实验板、ISP编程器、AT89S51实验芯片、豪华型多功能红外线遥控器。

图7：S51增强型单片机实验板及防插反红外遥控接口

图8：豪华型多功能红外遥控器 ＋ 高灵敏度一体化红外接收头（23元）

图9：32键豪华型红外遥控器原理图

图10：ISP编程器烧写实验单片机芯片AT89S51

　【红外遥控解码实验】

　　我们经过对前面的遥控编解码知识的学习，对红外遥控有了基本的了解，下面我们马上进行解码实验。本红外遥控解码实验的的功能是：程序对遥控器发射的遥控码进行解码，解码成功时蜂鸣器发出"嘀嘀"的解码成功提示音，如果按压的是数字键"0～9"就将按键值在实验板上的5位数码管上显示出按键值，同时将按键的十六进制值用P1口的8位发光二极管指示出来；如果按压的不是数字键"0～9"，就直接从P1口输出键值；下面是遥控解码汇编源程序。

　　实验时将先连接好硬件设备，将配套的一体化红外遥控接收头插入实验板上的"红外遥控"接口内，在Keil单片机集成开发环境中新建工程，通过Keil将源程序编译得到HEX格式目标文件yk.hex，最后使用ISP编程器将目标文件烧写到AT89S51单片机中，插到S51增强型实验板上运行，拿出配套的红外遥控器进行解码测试，看看实验结果是否和程序相同。。。

　　>>> 点此下载HEX格式目标文件 yk.hex >>>
　　>>> 点此下载遥控解码源程序和Keil工程文件 >>>

　　　　ORG　　 0000H
MAIN:　 MOV　　 SP,#60H
　　　　MOV　　 P0,#0FFH
　　　　MOV　　 P1,#0FFH
　　　　MOV　　 P2,#0FFH
　　　　MOV　　 P3,#0FFH
　　　　JNB　　 P3.2,$　　　　;等待遥控信号出现
　　　　MOV　　 R6,#10
SB: 　　ACALL　 YS1　　　　　 ;调用882微秒延时子程序
　　　　JB　　　P3.2,MAIN　　 ;延时882微秒后判断P3.2脚是否出现高电平如果有就退出解码程序
　　　　DJNZ　　R6, SB　　　　;重复10次，目的是检测在8820微秒内如果出现高电平就退出解码程序
　　　　　　　　　　　　　　　;以上完成对遥控信号的9000微秒的初始低电平信号的识别。
　　　　JNB　　 P3.2, $ 　　　;等待高电平避开9毫秒低电平引导脉冲
　　　　ACALL　 YS2 　　　　　;延时4.74毫秒避开4.5毫秒的结果码
　　　　MOV　　 R1,#1AH 　　　;设定1AH为起始RAM区
　　　　MOV　　 R2,#4
PP: 　　MOV　　 R3,#8
JJJJ: 　JNB　　 P3.2,$　　　　;等待地址码第一位的高电平信号
　　　　LCALL　 YS1　　　　　 ;高电平开始后用882微秒的时间尺去判断信号此时的高低电平状态
　　　　MOV　　 C,P3.2　　　　;将P3.2引脚此时的电平状态0或1存入C中
　　　　JNC　　 UUU　　　　　 ;如果为0就跳转到UUU
　　　　JB　　　P3.2,$　　　　;如果为1就等待高电平信号结束
UUU: 　 MOV　　 A,@R1　　　　 ;将R1中地址的给A
　　　　RRC　　 A　　　　　　 ;将C中的值0或1移入A中的最低位
　　　　MOV　　 @R1,A　　　　 ;将A中的数暂时存放在R1中
　　　　DJNZ　　R3,JJJJ　　　 ;接收地址码的高8位
　　　　INC　　 R1　　　　　　;对R1中的值加1，换成下一个RAM
　　　　DJNZ　　R2,PP 　　　　;接收完16位地址码和8位数据码和8位数据反码，存放在1AH/1BH/1CH/1DH的RAM中
　　　　　　　　　　　　　　　;以下对代码是否正确和定义进行识别
　　　　MOV　　 A,1AH　　　　 ;比较高8位地址码
　　　　XRL　　 A,#00000000B　;判断1AH的值是否等于00000000，相等的话A为0
　　　　JNZ　　 MAIN　　　　　;如果不相等说明解码失败退出解码程序
　　　　MOV　　 A,1BH　　　　 ;比较低8位地址
　　　　XRL　　 A,#11111111B　;再判断高8位地址是否正确
　　　　JNZ　　 MAIN　　　　　;如果不相等说明解码失败退出解码程序
　　　　MOV　　 A,1CH　　　　 ;比较数据码和数据反码是否正确?
　　　　CPL　　 A
　　　　XRL　　 A,1DH 　　　　;将1CH的值取反后和1DH比较 不同则无效丢弃，核对数据是否准确
　　　　JNZ　　 MAIN　　　　　;如果不相等说明解码失败退出解码程序
　　　　LCALL　 SOUND　　　　 ;解码成功，声音提示
　　　　MOV　　 A,1AH
　　　　CPL　　 A
　　　　MOV　　 P1,A　　　　　;遥控码十六进制值通过P1口LED显示出来

;-------- 下面为0～9键码判断并在实验板的5位数码管中显示键值 --------
JZPD: 　MOV　　 A,1AH
IRD0: 　CJNE　　A,#00H,IRD1　 ;按键"0"判断显示
　　　　MOV　　 P0,#0C0H
　　　　MOV　　 P2,#11100000B
　　　　AJMP　　MAIN
IRD1: 　CJNE　　A,#01H,IRD2　 ;按键"1"判断显示
　　　　MOV　　 P0,#0F9H
　　　　MOV　　 P2,#11100000B
　　　　AJMP　　MAIN
IRD2:　 CJNE　　A,#02H,IRD3　 ;按键"2"判断显示
　　　　MOV　　 P0,#0A4H
　　　　MOV　　 P2,#11100000B
　　　　AJMP　　MAIN
IRD3:　 CJNE　　A,#03H,IRD4　 ;按键"3"判断显示
　　　　MOV　　 P0,#0B0H
　　　　MOV　　 P2,#11100000B
　　　　AJMP　　MAIN
IRD4: 　CJNE　　A,#04H,IRD5　 ;按键"4"判断显示
　　　　MOV　　 P0,#99H
　　　　MOV　　 P2,#11100000B
　　　　AJMP　　MAIN
IRD5: 　CJNE　　A,#05H,IRD6　 ;按键"5"判断显示
　　　　MOV　　 P0,#92H
　　　　MOV　　 P2,#11100000B
　　　　AJMP　　MAIN
IRD6: 　CJNE　　A,#06H,IRD7　 ;按键"6"判断显示
　　　　MOV　　 P0,#82H
　　　　MOV　　 P2,#11100000B
　　　　AJMP　　MAIN
IRD7:　 CJNE　　A,#07H,IRD8　 ;按键"7"判断显示
　　　　MOV　　 P0,#0F8H
　　　　MOV　　 P2,#11100000B
　　　　AJMP　　MAIN
IRD8: 　CJNE　　A,#08H,IRD9　 ;按键"8"判断显示
　　　　MOV　　 P0,#80H
　　　　MOV　　 P2,#11100000B
　　　　AJMP　　MAIN
IRD9:　 CJNE　　A,#09H,IRDOR　 ;按键"9"判断显示
　　　　MOV　　 P0,#90H
　　　　MOV　　 P2,#11100000B
　　　　AJMP　　MAIN

IRDOR:　MOV　　 P2,#0FFH　 　 　;关闭数码管使能。"0～9"以外的非数字功能按键键值不采用数码管显示，直接从P1口输出键值
　　　　AJMP　　MAIN

YS1: 　 MOV　　 R4,#19 ;延时子程序1
D1: 　　MOV　　 R5,#18
　　　　DJNZ　　R5,$
　　　　DJNZ　　R4,D1
　　　　RET

YS2: 　 MOV　　 R4,#10 ;延时子程序2
D2: 　　MOV　　 R5,#216
　　　　DJNZ　　R5,$
　　　　DJNZ　　R4,D2
　　　　RET

SOUND:　MOV　　 R7,#228 ;音效延时子程序
SDL1: 　CPL　　 P3.7
　　　　MOV　　 R6,#0FFH
SDL0: 　DJNZ　　R6,SDL0
　　　　DJNZ　　R7,SDL1
　　　　RET

　　把上面程序写入at89S51单片机中，一个简单的单片机红外遥控器设计就完成了哈哈，是不是很有兴趣了，通电后，按压遥控器上的0～9按键，则实验板上的数码管上就显示出对应的按键值，同时解码成功后发出声音指示。。。